UNE FORMULE – MILLE ET UNE IMAGES

Grace aux differents sets de coefficients :
A=coefficient de X, B=coefficient de Y, X=abscisse de départ, Y=ordonnée de départ En réalité , les coordonée sont volontairement inversées pour le dessin ( voir CURSET ), pour obtenir l’image à symétrie horizontale, plus jolie et plus logique que la symétrie verticale obtenu par l’equation donnant une image couché.

100 HIRES:PAPER0:INK7
110 INPUT « NUMERO DU SET 1 A 12, 13 PERSO »;M
120 ON M GOSUB 600,610,620,630,640,650,660,670,680,690,700,710,720
130 S2=S1*200/240:GOSUB 500
140 X1=B*Y+F
150 X2=X:X=X1:GOSUB 500
160 X=X2:Y1=-X+F
170 X=X1:Y=Y1
180 IF 119+S1*X<0 OR 119+S1*X>239 THEN140
190 IF 99+S2*Y<0 OR 99+S2*Y>199 THEN140
200 CURSET 119+S1*Y,99+S2*X,1
210 GOTO 140
500 F=A*X+(1-A)*2*X^2/(1+X^2)
510 RETURN
600 A=-0.4:B=1:X=4:Y=0:S1=7:RETURN
610 A=-0.3:B=1:X=2:Y=0:S1=9:RETURN
620 A=-0.05:B=1:X=15:Y=0:S1=7:RETURN
630 A=0.18:B=1:X=5.3:Y=0:S1=15:RETURN
640 A=0.7:B=0.998:X=0:Y=12:S1=7:RETURN
650 A=0.2:B=1:X=10:Y=0:S1=6:RETURN
660 A=0.31:B=1:X=12:Y=0:S1=4:RETURN
670 A=0.32:B=1:X=5:Y=0:S1=7:RETURN
680 A=0.3:B=1:X=7:Y=0:S1=5:RETURN
690 A=-0.05:B=1:X=2:Y=0:S1=10:RETURN
700 A=-0.4:B=0.99:X=4:Y=0:S1=12:RETURN
710 A=-0.48:B=0.93:X=4:Y=0:S1=10:RETURN
720 INPUT »COEFICIENT A ? »;A
730 INPUT »COEFICIENT B ? »;B
740 INPUT »X DE DEPART ? »;X
750 INPUT »Y DE DEPART ? »;Y
760 INPUT »C AJUSTEMENT ECRAN »;S1
770 RETURN
POUR LA COULEUR AJOUTER
101 FOR Y= 109 TO 199 STEP4:CURSET 6,Y,3
102 FILL 1,1,1:FILL 1,1,2:FILL1,1,1:FILL 1,1,3:NEXT Y
103 FOR Y=109 TO 0 STEP-4:CURSET 6,Y,3
104 FILL1,1,1:FILL 1,1,3:FILL1,1,1:FILL1,1,2:NEXT Y
105 REM POUR JULIA SEULEMENT LIGNES 106-109
106 FOR Y= 89 TO 199 STEP4:CURSET119,Y,3
107 FILL 1,1,1:FILL 1,1,2:FILL1,1,1:FILL 1,1,3:NEXT Y
108 FOR Y=89 TO 0 STEP-4:CURSET119,Y,3
109 FILL1,1,1:FILL 1,1,3:FILL1,1,1:FILL1,1,2:NEXT Y

DES QUE L’IMAGE VOUS PLAIT ARRETEZ LE PROGRAMME (CTRL-C)